Buff Averages by Buff Dormeier

This month in Traders' Tips, we'll be buffing up your moving averages using the volume-weighting method presented in Buff Dormeier's article in this issue, "Buff Up Your Moving Averages." The weighting formula has
been created as a function in EasyLanguage so that it can be referenced from any analysis technique or strategy. In addition, a simple two-line volume-weighted average indicator that references the function has also
been included.

The name of the volume-weighted average function is "BuffAverage." The function has two inputs, price and length. The price input represents the price value upon which the average calculation is based. The length input
represents the number of bars that are used in the calculation of the average. Here is the EasyLanguage for the function:

Typ : Function, Name : BuffAverage

Inputs: Price(Numeric), Length(Numeric);
Variables: VolSum(0), Buff(0);

VolSum = Summation(Volume, Length);
Buff = 0;

If VolSum <> 0 Then Begin
For value1 = 0 To Length - 1 Begin
Buff = Buff + ((Price[value1] * Volume[value1]) / VolSum);
End;
End;

BuffAverage = Buff;


Typ : Indicator, Name : Buff Averages

Inputs: Price(Close), FastAvg(5), SlowAvg(20);

Plot1(BuffAverage(Price, FastAvg), "FastBuff");
Plot2(BuffAverage(Price, SlowAvg), "SlowBuff");

If Plot1 Crosses Above Plot2 Then
       Alert("Buff Averages Bullish Crossover.");
If Plot1 Crosses Below Plot2 Then
        Alert("Buff Averages Bearish Crossover.");

Chart style:
PlotName   Style    Weight
FastBuff   Line     Thinnest
SlowBuff   Line     Thinnest

Chart color:
PlotName   Color
FastBuff   Magenta
SlowBuff   Cyan

Scaling: Same as symbol.